*DECK PRO6P2
      SUBROUTINE INITAL
C...
C...  TWO DIMENSIONAL BURGERS' EQUATION WITH DIRICHLET AND NEUMANN
C...  BOUNDARY CONDITIONS, ILLUSTRATING THE NUMERICAL METHOD OF LINES
C...  INTEGRATION OF TWO DIMENSIONAL ELLIPTIC, HYPERBOLIC AND PARABOLIC
C...  PARTIAL DIFFERENTIAL EQUATIONS (PDES)
C...
C...  THIS PROBLEM ILLUSTRATES THE METHOD OF LINES PROGRAMMING OF A
C...  TWO DIMENSIONAL HYPERBOLIC PARABOLIC (CONVECTIVE DIFFUSION)
C...  PARTIAL DIFFERENTIAL EQUATION (PDE), THE WELL KNOWN BURGERS'
C...  EQUATION
C...
C...     U  = -U*U  + VIS*U   - U*U  + VIS*U                   (1)
C...      T       X        XX      Y        YY
C...
C...  WHERE
C...
C...     U       DEPENDENT VARIABLE TO BE COMPUTED
C...
C...     T       INITIAL VALUE INDEPENDENT VARIABLE (TYPICALLY TIME)
C...
C...     X,Y     BOUNDARY VALUE INDEPENDENT VARIABLES (TYPICALLY SPACE)
C...
C...     VIS     COEFFICIENT, TYPICALLY A VISCOSITY, WHICH CHANGES THE
C...             CHARACTER OF EQUATION (1)
C...
C...                VIS LARGE - EQUATION (1) IS STRONGLY PARABOLIC
C...
C...                VIS SMALL - EQUATION (1) IS STRONGLY HYPERBOLIC
C...
C...  A LETTER SUBSCRIPT DENOTES A PARTIAL DERIVATIVE, E.G., U  IS THE
C...                                                          T
C...  FIRST ORDER PARTIAL DERIVATIVE OF U WITH RESPECT TO T.
C...
C...  EQUATION (1) IS A WELL-ESTABLISHED TEST PROBLEM FOR PDE SOFTWARE
C...  BECAUSE IT
C...
C...     (1)  HAS AN EXACT SOLUTION, E.G.,
C...
C...          U(X,Y,T) =
C...                                                            (2)
C...          1/(1 + EXP(X/(2*VIS) + Y/(2*VIS) - 2*T/(4*VIS)))
C...
C...     (2)  IS A STRINGENT TEST PROBLEM, PARTICULARLY FOR SMALL VIS,
C...          FOR WHICH THE SOLUTION EXHIBITS STEEP, MOVING FRONTS.
C...
C...  IN THE SUBSEQUENT PROGRAMMING OF EQUATION (1), THE INITIAL AND
C...  BOUNDARY CONDITIONS HAVE BEEN CHOSEN TO BE CONSISTENT WITH
C...  EQUATION (2).  ALSO, VIS = 1.0, WHICH GIVES EQUATION (1) A
C...  MIXED HYPERBOLIC PARABOLIC CHARACTER, RESULTS IN A VERY SMOOTH
C...  SOLUTION FROM EQUATION (2), I.E., THIS CHOICE OF VIS WAS MADE
C...  TO FACILITATE THE CALCULATION OF THE NUMERICAL SOLUTION IN ORDER
C...  TO DEMONSTRATE VARIOUS COMPUTATIONAL AND PROGRAMMING PROCEDURES
C...  WITH A MODEST COMPUTING EFFORT.
C...
C...  EQUATION (1) IS INTEGRATED BY THE NUMERICAL METHOD OF LINES IN
C...  THE SUBSEQUENT PROGRAMMING FOR TWO TYPES OF BOUNDARY CONDITIONS
C...  AT X = 0 AND X =XL, Y = 0 AND Y = YL (IN THE SUBSEQUENT DISCUSSION
C...  XL AND YL HAVE THE NUMERICAL VALUES XL = YL = 1)
C...
C...     (1)  DIRICHLET BOUNDARY CONDITIONS IN WHICH U(0,Y,T),
C...          U(X,0,T), U(XL,Y,T) AND U(X,YL,T) ARE SPECIFIED
C...
C...     (2)  NEUMANN BOUNDARY CONDITIONS IN WHICH U (0,Y,T),
C...                                                X
C...          U (X,YL,T), U (X,0,T) AND U (XL,Y,T) ARE SPECIFIED.
C...           X           Y             Y
C...
C...  IN THE SUBSEQUENT DISCUSSION, THE DERIVATIVES IN EQUATION (1)
C...  WILL BE DESIGNATED WITH IN LINE NOTATION, E.G., U   WILL BE
C...                                                   XX
C...  DESIGNATED UXX.
C...
C...  SINCE THE EXACT SOLUTION, EQUATION (2), IS AVAILABLE, THE ERROR
C...  IN THE NUMERICAL SOLUTION CAN BE COMPUTED.  IN PARTICULAR, THE
C...  ERROR IN U(X=XL/2,Y=YL/2,T=1) IS COMPUTED FROM THE FOLLOWING
C...  APPLICATION OF EQUATION (2)
C...
C...  U(0.5,0.5,1) = 1/(1 + EXP(0.5/(2*VIS) +0.5/(2*VIS) - 2*1/(4*VIS)))
C...
C...                 = 1/(1 + EXP(0)) = 0.5
C...
C...  NOTE THAT THIS RESULT IS INDEPENDENT OF VIS.  THUS, VIS CAN BE
C...  DECREASED TO MAKE THE NUMERICAL SOLUTION MORE DIFFICULT TO
C...  COMPUTE, I.E., THE PROBLEM IS MORE HYPERBOLIC AND LESS PARABOLIC,
C...  YET THE NUMERICAL SOLUTION SHOULD REMAIN CLOSE TO 0.5 IF REASON-
C...  ABLE ACCURACY IS TO BE MAINTAINED.
C...
C...  IN ADDITION TO THE COMMENTS IN THE FOLLOWING CODING, THE READER
C...  CAN ALSO REFER TO THE COMMENTS IN THE SPATIAL DIFFERENTIATION
C...  SUBROUTINE, DSS034.  IN PARTICULAR, CENTERED APPROXIMATIONS IN
C...  SUBROUTINE DSS034 ARE USED TO CALCULATE UXX AND UYY IN EQUATION
C...  (1), I.E., CENTERED APPROXIMATIONS SHOULD BE USED IN PARABOLIC
C...  PROBLEMS, AND NONCENTERED (FIVE POINT BIASED UPWIND) APPROXI-
C...  MATIONS IN SUBROUTINE DSS034 ARE USED TO CALCULATE UX AND UY IN
C...  EQUATION (1), I.E., NONCENTERED APPROXIMATIONS SHOULD BE USED
C...  IN HYPERBOLIC PROBLEMS.  ALL OF THESE APPROXIMATIONS ARE DERIVED
C...  FROM THE TAYLOR SERIES AS EXPLAINED IN DSS034, AND SUBORDINATE
C...  ROUTINES DSS004 AND DSS020.
C...
C...  TWO SPECIAL CASES OF THIS PROBLEM CAN BE CONSIDERED
C...
C...     (1)  VIS = 0
C...
C...     IN THIS CASE, EQUATION (1) REDUCES TO
C...
C...     U  = - U*U  - U*U  = - (U**2) /2 - (U**2) /2           (3)
C...      T        X      Y           X           Y
C...
C...     EQUATION (3) HAS THE ANALYTICAL SOLUTION
C...
C...     U(X,Y,T) = (X + Y)/(1 + 2*T)                           (4)
C...
C...     THE USE OF EQUATIONS (3) AND (4) IN THE FOLLOWING PROGRAMMING
C...     REQUIRES SOME MODIFICATION OF THE PROGRAMMING.
C...
C...     (2)  BOUNDARY VALUE PARTIAL DIFFERENTIAL EQUATION (PDE)
C...
C...     THE STEADY STATE FORM OF EQUATION (1) IS THE BOUNDARY VALUE
C...     PARTIAL DIFFERENTIAL EQUATION
C...
C...     U   - U*U  + U   - U*U  = 0                            (5)
C...      XX      X    YY      Y
C...
C...     (NOTE THAT U  = 0 IN EQUATION (1)), WHICH CAN ALSO BE CONSIDER-
C...                 T
C...     ED AS A TWO DIMENSIONAL ELLIPTIC PDE (WITH INDEPENDENT VARI-
C...     ABLES X AND Y).  THUS, THE FOLLOWING PROGRAMMING ILLUSTRATES A
C...     METHOD FOR INTEGRATING ELLIPTIC PDES AS WELL AS HYPERBOLIC
C...     AND PARABOLIC PDES (BY ALLOWING THE SOLUTION OF EQUATION (1)
C...     TO PROCEED TO U  = 0, FOR WHICH EQUATION (2), WITH LARGE T,
C...                    T
C...     REDUCES TO:
C...
C...        U(X,Y,INF) = 1
C...
C...     THIS DISCUSSION SUGGESTS A GENERAL METHOD FOR SOLVING BOUNDARY
C...     VALUE PDES, I.E., A PSEUDO TIME DERIVATIVE IS ADDED TO THE PDES
C...     AND THE RESULTING PDES ARE INTEGRATED TO STEADY STATE FOR WHICH
C...     THE TIME DERIVATIVES ESSENTIALLY GO TO ZERO.  THIS APPROACH HAS
C...     BEEN USED EFFECTIVELY IN THE SOLUTION OF SOME RELATIVELY COM-
C...     PLEX BOUNDARY VALUE PDES.  THIS APPROACH IS ALSO TERMED THE
C...     METHOD OF FALSE TRANSIENTS.
C...
C...  FINALLY, THE VERIFICATION OF EQUATION (2) AS A SOLUTION TO EQUA-
C...  TION (1) FOLLOWS:
C...
C...  LET EX = EXP(X/(2*VIS) + Y/(2*VIS) - 2*T/(4*VIS)).  THEN EQUATION
C...  (2) CAN BE WRITTEN AS:
C...
C...     U(X,Y,T) = 1/(1 + EX)
C...
C...  THE VARIOUS TERMS IN EQUATION (1) ARE:
C...
C...     U  = (-1/(1 + EX)**2)*EX*(-2/(4*VIS))
C...      T
C...
C...     U*U  = (1/(1 + EX))*(-1/(1 + EX)**2)*EX*(1/(2*VIS))
C...        X
C...
C...     -VIS*U   = -VIS*((-1/(1 + EX)**2)*EX*(1/(2*VIS))**2
C...           XX
C...
C...              + EX*(1/(2*VIS)*2/(1 + EX)**3)*EX*(1/(2*VIS)))
C...
C...     U*U  = (1/(1 + EX))*(-1/(1 + EX)**2)*EX*(1/(2*VIS))
C...        Y
C...
C...     -VIS*U   = -VIS*((-1/(1 + EX)**2)*EX*(1/(2*VIS))**2
C...           YY
C...
C...              + EX*(1/(2*VIS)*2/(1 + EX)**3)*EX*(1/(2*VIS)))
C...
C...  SUMMATION OF THESE TERMS GIVES:
C...
C...     0 = (1/(1 + EX)**2)*EX*(1/(4*VIS))*(2 + 1 + 1)
C...
C...       - (1/(1 + EX)**3)*EX*(1/(2*VIS))*(1 + 1)*(1 + EX)
C...
C...       = 0
C...
C...  WE NOW PROCEED TO THE NUMERICAL METHOD OF LINES SOLUTION OF EQUA-
C...  TION (1) SUBJECT TO DIRICHLET AND NEUMANN BOUNDARY CONDITIONS, AND
C...  AN INITIAL CONDITION, WHICH ARE CONSISTENT WITH THE EXACT SOLU-
C...  TION, EQUATION (2).
C...
C...  ODE COMMON
      COMMON/T/         T,     NSTOP,     NORUN
     1      /Y/  U(11,11)
     2      /F/ UT(11,11)
     3      /S/ UX(11,11),UXX(11,11),
     4          UY(11,11),UYY(11,11)
     5      /R/        XL,        YL,
     6              X(11),     Y(11),
     7                VIS
     8      /I/        NX,        NY,
     9                 IP
C...
C...  EQUATION PARAMETERS
      VIS=1.0E+00
      XL=1.0E+00
      YL=1.0E+00
C...
C...  NUMBER OF GRID POINTS
      NX=11
      NY=11
C...
C...  INITIAL CONDITIONS (T = 0 IN EQUATION (2))
      DO 1 I=1,NX
      X(I)=XL*FLOAT(I-1)/FLOAT(NX-1)
      DO 1 J=1,NY
      Y(J)=YL*FLOAT(J-1)/FLOAT(NY-1)
      U(I,J)=UA(X(I),Y(J),T,VIS)
1     CONTINUE
C...
C...  INITIAL DERIVATIVES
      CALL DERV
      IP=0
      RETURN
      END
      SUBROUTINE DERV
      COMMON/T/         T,     NSTOP,     NORUN
     1      /Y/  U(11,11)
     2      /F/ UT(11,11)
     3      /S/ UX(11,11),UXX(11,11),
     4          UY(11,11),UYY(11,11)
     5      /R/        XL,        YL,
     6              X(11),     Y(11),
     7                VIS
     8      /I/        NX,        NY,
     9                 IP
C...
C...  DIRICHLET BOUNDARY CONDITIONS WITH (1) UXX AND UYY CALCULATED BY
C...  CENTERED APPROXIMATIONS AND (2) UX AND UY CALCULATED BY BIASED
C...  UPWIND APPROXIMATIONS
      IF(NORUN.EQ.1)CALL DERV1
C...
C...  DIRICHLET BOUNDARY CONDITIONS WITH UXX, UYY, UX AND UY CALCULATED
C...  BY CENTERED APPROXIMATIONS
      IF(NORUN.EQ.2)CALL DERV2
C...
C...  NEUMANN BOUNDARY CONDITIONS WITH (1) UXX AND UYY CALCULATED BY
C...  CENTERED APPROXIMATIONS AND (2) UX AND UY CALCULATED BY BIASED
C...  UPWIND APPROXIMATIONS
      IF(NORUN.EQ.3)CALL DERV3
C...
C...  NEUMANN BOUNDARY CONDITIONS WITH UXX, UYY, UX AND UY CALCULATED
C...  BY CENTERED APPROXIMATIONS
      IF(NORUN.EQ.4)CALL DERV4
      RETURN
      END
      SUBROUTINE DERV1
C...
C...  DIRICHLET BOUNDARY CONDITIONS
C...
      COMMON/T/         T,     NSTOP,     NORUN
     1      /Y/  U(11,11)
     2      /F/ UT(11,11)
     3      /S/ UX(11,11),UXX(11,11),
     4          UY(11,11),UYY(11,11)
     5      /R/        XL,        YL,
     6              X(11),     Y(11),
     7                VIS
     8      /I/        NX,        NY,
     9                 IP
C...
C...     X = 0, 0 LE Y LE YL (X = 0 IN EQUATION (2))
         DO 1 J=1,NY
         U(1,J)=UA(X(1),Y(J),T,VIS)
1        CONTINUE
C...
C...     X = XL, 0 LE Y LE YL (X = XL IN EQUATION (2))
         DO 2 J=1,NY
         U(NX,J)=UA(X(NX),Y(J),T,VIS)
2        CONTINUE
C...
C...     Y = 0, 0 LE X LE XL (Y = 0 IN EQUATION (2))
         DO 3 I=1,NX
         U(I,1)=UA(X(I),Y(1),T,VIS)
3        CONTINUE
C...
C...     Y = YL, 0 LE X LE XL (Y = YL IN EQUATION (2))
         DO 4 I=1,NX
         U(I,NY)=UA(X(I),Y(NY),T,VIS)
4        CONTINUE
C...
C...  SPATIAL DERIVATIVES
C...
C...     UX IN UXX (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,U,UX,0.E+00)
C...
C...     UXX (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,UX,UXX,0.E+00)
C...
C...     UX IN U*UX (BY FIVE POINT BIASED UPWIND APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,U,UX,1.0E+00)
C...
C...     UY IN UYY (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,U,UY,0.E+00)
C...
C...     UYY (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,UY,UYY,0.E+00)
C...
C...     UY IN U*UY (BY FIVE POINT BIASED UPWIND APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,U,UY,1.0E+00)
C...
C...  BURGERS' EQUATION
C...
         DO 10 I=1,NX
         DO 10 J=1,NY
         UT(I,J)=-U(I,J)*UX(I,J)+VIS*UXX(I,J)
     1           -U(I,J)*UY(I,J)+VIS*UYY(I,J)
10       CONTINUE
      RETURN
      END
      SUBROUTINE DERV2
C...
C...  DIRICHLET BOUNDARY CONDITIONS
C...
      COMMON/T/         T,     NSTOP,     NORUN
     1      /Y/  U(11,11)
     2      /F/ UT(11,11)
     3      /S/ UX(11,11),UXX(11,11),
     4          UY(11,11),UYY(11,11)
     5      /R/        XL,        YL,
     6              X(11),     Y(11),
     7                VIS
     8      /I/        NX,        NY,
     9                 IP
C...
C...     X = 0, 0 LE Y LE YL (X = 0 IN EQUATION (2))
         DO 1 J=1,NY
         U(1,J)=UA(X(1),Y(J),T,VIS)
1        CONTINUE
C...
C...     X = XL, 0 LE Y LE YL (X = XL IN EQUATION (2))
         DO 2 J=1,NY
         U(NX,J)=UA(X(NX),Y(J),T,VIS)
2        CONTINUE
C...
C...     Y = 0, 0 LE X LE XL (Y = 0 IN EQUATION (2))
         DO 3 I=1,NX
         U(I,1)=UA(X(I),Y(1),T,VIS)
3        CONTINUE
C...
C...     Y = YL, 0 LE X LE XL (Y = YL IN EQUATION (2))
         DO 4 I=1,NX
         U(I,NY)=UA(X(I),Y(NY),T,VIS)
4        CONTINUE
C...
C...  SPATIAL DERIVATIVES
C...
C...     UX (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,U,UX,0.E+00)
C...
C...     UXX (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,UX,UXX,0.E+00)
C...
C...     UY (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,U,UY,0.E+00)
C...
C...     UYY (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,UY,UYY,0.E+00)
C...
C...  BURGERS' EQUATION
C...
         DO 10 I=1,NX
         DO 10 J=1,NY
         UT(I,J)=-U(I,J)*UX(I,J)+VIS*UXX(I,J)
     1           -U(I,J)*UY(I,J)+VIS*UYY(I,J)
10       CONTINUE
      RETURN
      END
      SUBROUTINE DERV3
C...
C...  NEUMANN BOUNDARY CONDITIONS
C...
      COMMON/T/         T,     NSTOP,     NORUN
     1      /Y/  U(11,11)
     2      /F/ UT(11,11)
     3      /S/ UX(11,11),UXX(11,11),
     4          UY(11,11),UYY(11,11)
     5      /R/        XL,        YL,
     6              X(11),     Y(11),
     7                VIS
     8      /I/        NX,        NY,
     9                 IP
C...
C...  SPATIAL DERIVATIVES
C...
C...     UX IN UXX (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,U,UX,0.E+00)
C...
C...     X = 0, 0 LE Y LE YL (X = 0 IN EQUATION (2))
         DO 1 J=1,NY
         UX(1,J)=DUA(X(1),Y(J),T,VIS)
1        CONTINUE
C...
C...     X = XL, 0 LE Y LE YL (X = XL IN EQUATION (2))
         DO 2 J=1,NY
         UX(NX,J)=DUA(X(NX),Y(J),T,VIS)
2        CONTINUE
C...
C...     UXX (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,UX,UXX,0.E+00)
C...
C...     UX IN U*UX (BY FIVE POINT BIASED UPWIND APPROXIMATIONS)
         CALL DSS034(0.E+00,XL,NX,NY,1,U,UX,1.0E+00)
C...
C...     X = 0, 0 LE Y LE YL (X = 0 IN EQUATION (2))
         DO 3 J=1,NY
         UX(1,J)=DUA(X(1),Y(J),T,VIS)
3        CONTINUE
C...
C...     X = XL, 0 LE Y LE YL (X = XL IN EQUATION (2))
         DO 4 J=1,NY
         UX(NX,J)=DUA(X(NX),Y(J),T,VIS)
4        CONTINUE
C...
C...     UY IN UYY (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,U,UY,0.E+00)
C...
C...     Y = 0, 0 LE X LE XL (Y = 0 IN EQUATION (2))
         DO 5 I=1,NX
         UY(I,1)=DUA(X(I),Y(1),T,VIS)
5        CONTINUE
C...
C...     Y = YL, 0 LE X LE XL (Y = YL IN EQUATION (2))
         DO 6 I=1,NX
         UY(I,NY)=DUA(X(I),Y(NY),T,VIS)
6        CONTINUE
C...
C...     UYY (BY FIVE POINT CENTERED APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,UY,UYY,0.E+00)
C...
C...     UY IN U*UY (BY FIVE POINT BIASED UPWIND APPROXIMATIONS)
         CALL DSS034(0.E+00,YL,NX,NY,2,U,UY,1.0E+00)
C...
C...     Y = 0, 0 LE X LE XL (Y = 0 IN EQUATION (2))
         DO 7 I=1,NX
         UY(I,1)=DUA(X(I),Y(1),T,VIS)
7        CONTINUE
C...
C...     Y = YL, 0 LE X LE XL (Y = YL IN EQUATION (2))
         DO 8 I=1,NX
         UY(I,NY)=DUA(X(I),Y(NY),T,VIS)
8        CONTINUE
C...
C...  BURGERS' EQUATION
C...
         DO 10 I=1,NX
         DO 10 J=1,NY
         UT(I,J)=-U(I,J)*UX(I,J)+VIS*UXX(I,J)
     1           -U(I,J)*UY(I,J)+VIS*UYY(I,J)
10       CONTINUE
      RETURN
      END
      SUBROUTINE DERV4
C...
C...  NEUMANN BOUNDARY CONDITIONS
C...
      COMMON/T/         T,     NSTOP,     NORUN
     1      /Y/  U(11,11)
     2      /F/ UT(11,11)
     3      /S/ UX(11,11),UXX(11,11),
     4          UY(11,11),UYY(11,11)
     5      /R/        XL,        YL,
     6              X(11),     Y(11),
     7                VIS
     8      /I/        NX,        NY,
     9                 IP
C...
C...  SPATIAL DERIVATIVES
C...
C...     UX BY FIVE POINT CENTERED APPROXIMATIONS
         CALL DSS034(0.E+00,XL,NX,NY,1,U,UX,0.E+00)
C...
C...     X = 0, 0 LE Y LE YL (X = 0 IN EQUATION (2))
         DO 1 J=1,NY
         UX(1,J)=DUA(X(1),Y(J),T,VIS)
1        CONTINUE
C...
C...     X = XL, 0 LE Y LE YL (X = XL IN EQUATION (2))
         DO 2 J=1,NY
         UX(NX,J)=DUA(X(NX),Y(J),T,VIS)
2        CONTINUE
C...
C...     UXX BY FIVE POINT CENTERED APPROXIMATIONS
         CALL DSS034(0.E+00,XL,NX,NY,1,UX,UXX,0.E+00)
C...
C...     UY BY FIVE POINT CENTERED APPROXIMATIONS
         CALL DSS034(0.E+00,YL,NX,NY,2,U,UY,0.E+00)
C...
C...     Y = 0, 0 LE X LE XL (Y = 0 IN EQUATION (2))
         DO 5 I=1,NX
         UY(I,1)=DUA(X(I),Y(1),T,VIS)
5        CONTINUE
C...
C...     Y = YL, 0 LE X LE XL (Y = YL IN EQUATION (2))
         DO 6 I=1,NX
         UY(I,NY)=DUA(X(I),Y(NY),T,VIS)
6        CONTINUE
C...
C...     UYY BY FIVE POINT CENTERED APPROXIMATIONS
         CALL DSS034(0.E+00,YL,NX,NY,2,UY,UYY,0.E+00)
C...
C...  BURGERS' EQUATION
C...
         DO 10 I=1,NX
         DO 10 J=1,NY
         UT(I,J)=-U(I,J)*UX(I,J)+VIS*UXX(I,J)
     1           -U(I,J)*UY(I,J)+VIS*UYY(I,J)
10       CONTINUE
      RETURN
      END
      FUNCTION UA(X,Y,T,VIS)
C...
C...  FUNCTION UA IMLEMENTS THE ANALYTICAL SOLUTION, EQUATION (2)
C...
      EX=EXP(X/(2.0E+00*VIS)+Y/(2.0E+00*VIS)-T/(2.0E+00*VIS))
      UA=1.0E+00/(1.0E+00+EX)
      RETURN
      END
      FUNCTION DUA(X,Y,T,VIS)
C...
C...  FUNCTION DUA IMPLEMENTS THE DERIVATIVE OF THE ANALYTICAL SOLUTION,
C...  EQUATION (2), WITH RESPECT TO X AND Y
C...
      EX=EXP(X/(2.0E+00*VIS)+Y/(2.0E+00*VIS)-T/(2.0E+00*VIS))
      DUA=-1.0E+00*(1.0E+00+EX)**(-2)*EX*(1.0E+00/(2.0E+00*VIS))
      RETURN
      END
      SUBROUTINE PRINT(NI,NO)
      COMMON/T/         T,     NSTOP,     NORUN
     1      /Y/  U(11,11)
     2      /F/ UT(11,11)
     3      /S/ UX(11,11),UXX(11,11),
     4          UY(11,11),UYY(11,11)
     5      /R/        XL,        YL,
     6              X(11),     Y(11),
     7                VIS
     8      /I/        NX,        NY,
     9                 IP
C...
C...  PRINT A HEADING FOR THE NUMERICAL SOLUTION
      IP=IP+1
      IF(IP.EQ.1)WRITE(NO,1)
1     FORMAT(11X,'T',5X,'U(XL/2,YL/2,T)',
     1               3X,'U(XL/2,YL/2,T)',5X,'ERROR',/,
     2              20X,'  (NUM)  ',7X,'  (ANAL) ')
C...
C...  COMPUTE THE ANALYTICAL SOLUTION AND THE ERROR IN THE NUMERICAL
C...  SOLUTION AT X = XL/2, Y = YL/2
      NX2=NX/2+1
      NY2=NY/2+1
      XL2=X(NX2)
      YL2=Y(NY2)
      UANAL=UA(XL2,YL2,T,VIS)
      ERROR=U(NX2,NY2)-UANAL
C...
C...  PRINT THE NUMERICAL AND ANALYTICAL SOLUTIONS, AND THE ERROR
      WRITE(NO,2)T,U(NX2,NY2),UANAL,ERROR
2     FORMAT(F12.2,2F16.6,E16.4)
      RETURN
      END
