*DECK PRO2P3
      SUBROUTINE INITAL
C...
C...  SUBROUTINE INITAL IS CALLED BY MAIN PROGRAM PRO1P3 TO DEFINE THE
C...  INITIAL CONDITION IN THE NUMOL SOLUTION OF EQUATIONS (2.6) TO
C...  (2.9)
C...
C...  PLEASE NOTE:
C...
C...  (1)  THIS PROBLEM WAS ORIGINALLY DEVELOPED ON A LONG WORD LENGTH
C...       COMPUTER (64 BITS/WORD).  HOWEVER, WHEN IT WAS RUN ON A SHORT
C...       WORD LENGTH COMPUTER (32 BITS/WORD - A DEC VAX), THE SECOND
C...       RUN (M=4) TERMINATED WITH AN OVER FLOW WITHIN INTEGRATOR
C...       RKF45 WITHOUT GETTING PAST THE INITIAL CONDITION.  ATTEMPTS TO
C...       CIRCUMVENT THIS PROBLEM FAILED, INDICATING THAT THE PROBLEM
C...       MAY BE TOO STIFF FOR THIS EXPLICIT INTEGRATOR (THEREBY LEADING
C...       TO INSTABILITY AND MACHINE OVERFLOW - ALSO, STIFF PROBLEMS
C...       GENERALLY REQUIRE HIGHER PRECISION IN THE ARITHMETIC THAN
C...       NONSTIFF PROBLEMS, WHICH COULD ACCOUNT FOR THE SUCCESS WITH
C...       64-BIT ARITHMETIC AND FAILURE WITH 32-BIT ARITHMETIC).
C...
C...  (2)  TO TEST THIS HYPOTHESIS, THE PROBLEM WAS THEN RUN WITH DASSL VIA
C...       MAIN PROGRAM PRO4P5.MAIN, AND A SOLUTION WAS EASILY CALCULATED
C...       I.E., THE COMPUTATIONAL STATISTICS INDICATED A MODEST COMPUTA-
C...       TIONAL EFFORT.  THEREFORE, THIS PROBLEM MAY BE AN EXAMPLE OF
C...       HIGHER PRECISION REQUIREMENTS FOR STIFFER PROBLEMS.
C...
C...                                                   W. E. SCHIESSER
C...                                                       15AUG90
      COMMON/T/   TIME,    NSTOP,    NORUN
     1      /Y/  T(51)
     2      /F/ TT(51)
     3      /R/  X(51),   TX(51),  TXX(51),
     4               L,       DX
     5      /I/      N
C...
C...  TYPE SELECTED VARIABLES AS REAL
      REAL L
C...
C...  LENGTH
      L=1.0
C...
C...  GRID SPACING
      N=51
      DX=L/FLOAT(N-1)
C...
C...  INITIAL CONDITION (2.7)
      DO 1 I=1,N
         X(I)=FLOAT(I-1)*DX
         T(I)=0.
1     CONTINUE
      RETURN
      END
      SUBROUTINE DERV
C...
C...  SUBROUTINE DERV IS CALLED BY INTEGRATOR RKF45 TO DEFINE THE
C...  ODES IN THE NUMOL SOLUTION OF EQUATIONS (2.6) TO (2.9)
C...
      COMMON/T/   TIME,    NSTOP,    NORUN
     1      /Y/  T(51)
     2      /F/ TT(51)
     3      /R/  X(51),   TX(51),  TXX(51),
     4               L,       DX
     5      /I/      N
C...
C...  TYPE SELECTED VARIABLES AS REAL
      REAL L
C...
C...  BOUNDARY CONDITION (2.8)
       T(1)=1.
      TT(1)=0.
C...
C...  DERIVATIVE TX
      CALL DSS002(0.,L,N,T,TX)
C...
C...  BOUNDARY CONDITION (2.9)
C...
C...     LINEAR CASE
         IF(NORUN.EQ.1)M=1
C...
C...     NONLINEAR CASE
         IF(NORUN.EQ.2)M=4
C...
      TX(N)=(1.0-T(N)**M)
C...
C...  DERIVATIVE TXX
      CALL DSS002(0.,L,N,TX,TXX)
C...
C...  EQUATION (2.6)
      DO 2 I=2,N
      TT(I)=TXX(I)
2     CONTINUE
      RETURN
      END
      SUBROUTINE PRINT(NI,NO)
C...
C...  SUBROUTINE PRINT IS CALLED BY MAIN PROGRAM PRO1P3 TO PRINT THE
C...  NUMOL SOLUTION OF EQUATIONS (2.6) TO (2.9)
C...
      COMMON/T/   TIME,    NSTOP,    NORUN
     1      /Y/  T(51)
     2      /F/ TT(51)
     3      /R/  X(51),   TX(51),  TXX(51),
     4               L,       DX
     5      /I/      N
C...
C...  TYPE SELECTED VARIABLES AS REAL
      REAL L
C...
C...  PRINT THE NUMOL SOLUTION TO EQUATIONS (2.6) TO (2.9)
      WRITE(NO,2)TIME,(T(I),I=1,N,10)
2     FORMAT(' TIME = ',F6.2,/,15X,'  X=0',5X,'X=0.2',5X,'X=0.4',5X,
     1                             'X=0.6',5X,'X=0.8',5X,'  X=1',/,
     2                         '    T(X,T)',6F10.6,/)
      RETURN
      END
