      SUBROUTINE INITAL
C...
C...  NUMOL SOLUTION OF EQUATIONS (7.11), (7.50), (7.51), (7.52)
C...
      COMMON/T/   TIME
     1      /Y/  T(51)
     2      /F/ TT(51)
     3      /I/      N,      L
C...
C...  TYPE SELECTED VARIABLES AS REAL
      REAL L
C...
C...  LENGTH
      L=1.0
C...
C...  NUMBER OF GRID POINTS
      N=51
C...
C...  INITIAL CONDITION (7.52)
      DO 1 I=1,N
         T(I)=0.
1     CONTINUE
      RETURN
      END
      SUBROUTINE DERV
      COMMON/T/   TIME
     1      /Y/  T(51)
     2      /F/ TT(51)
     3      /I/      N,      L
C...
C...  TYPE SELECTED VARIABLES AS REAL
      REAL L, TX(51), TXX(51)
C...
C...  DERIVATIVE TX
      CALL DSS002(0.,L,N,T,TX)
C...
C...  BOUNDARY CONDITION (7.50)
      TX(1)=0.
C...
C...  BOUNDARY CONDITION (7.51)
      TX(N)=(1.0-T(N)**4)
C...
C...  DERIVATIVE TXX
      CALL DSS002(0.,L,N,TX,TXX)
C...
C...  EQUATION (7.11)
      DO 2 I=1,N
      TT(I)=TXX(I)
2     CONTINUE
      RETURN
      END
      SUBROUTINE PRINT(NI,NO)
      COMMON/T/   TIME
     1      /Y/  T(51)
     2      /F/ TT(51)
     3      /I/      N,      L
C...
C...  TYPE SELECTED VARIABLES AS REAL
      REAL L
C...
C...  PRINT THE NUMOL SOLUTION 
      WRITE(NO,2)TIME,(T(I),I=1,N,10)
2     FORMAT(' TIME = ',F6.2,/,15X,'  X=0',5X,'X=0.2',5X,'X=0.4',5X,
     1                             'X=0.6',5X,'X=0.8',5X,'  X=1',/,
     2                         '    T(X,T)',6F10.6,/)
      RETURN
      END
